C DEVEQ2    SOURCE    CHAT      05/01/12    22:44:58     5004           
      SUBROUTINE DEVEQ2(Q2,NA1,XK,XASM,XM,XDT,NPAS,FTOTA,FINERT)                
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)                                                  
*--------------------------------------------------------------------*          
*                                                                    *          
*     Op{rateur DYNE : algorithme de Fu - de Vogelaere               *          
*     ________________________________________________               *          
*                                                                    *          
*     Calcul des vitesses g{n{ralis{es pour le premier demi-pas      *          
*     de temps.                                                      *          
*                                                                    *          
*     Param}tres:                                                    *          
*                                                                    *          
* es  Q2(.,.) Vecteur des vitesses g{n{ralis{es                      *          
* e   NA1     Nombre total d'inconnues dans la base A                *          
* e   XK      Vecteur des raideurs g{n{ralis{es                      *          
* e   XASM    Vecteur des amortissements g{n{ralis{s                 *          
* e   XM      Vecteur des masses g{n{ralis{es                        *          
* e   XDT     Valeurs des pas de temps                               *          
* e   NPAS    Num{ro du pas de temps                                 *          
* e   FTOTA   Forces ext{rieures totalis{es, sur la base A           *          
*                                                                    *          
*     Auteur, date de cr{ation:                                      *          
*                                                                    *          
*     Denis ROBERT-MOUGIN, le 19 mai 1989.                           *          
*                                                                    *          
*--------------------------------------------------------------------*          
      REAL*8 XK(*),XASM(*),XM(*),XDT(*),FTOTA(NA1,*),Q2(NA1,*)                  
      REAL*8 FINERT(NA1,*)                                                      
*                                                                               
      PDT = XDT(NPAS)                                                           
      PDTS4 = PDT / 4.D0                                                        
*                                                                               
*     .             4       .                                 .                 
*     Q        = ________ ( Q    + h/4 ( G    + G        - A  Q   ) )           
*      i,m+1/2   4 + A  h    i,m          i,m    i,m+1/2    i  i,m              
*                     I                                                         
*                                                                               
*     Boucle sur les inconnues de la base A                                     
*                                                                               
      DO 10 IA = 1,NA1                                                          
         UNSM2 = 1.D0 / ( XM(IA) - FINERT(IA,2) )                               
         UNSM3 = 1.D0 / ( XM(IA) - FINERT(IA,3) )                               
         AUX1 = 4.D0 / ( 4.D0 + ( XASM(IA) * UNSM2 * PDT ) )                    
         AUX2 = ( FTOTA(IA,3) * UNSM3 ) + ( FTOTA(IA,2) * UNSM2 )               
     &                        - ( XASM(IA) * UNSM3 * Q2(IA,3) )                 
         AUX3 = Q2(IA,3) + ( PDTS4 * AUX2 )                                     
         Q2(IA,2) = AUX1 * AUX3                                                 
 10      CONTINUE                                                               
*     end do                                                                    
*                                                                               
      END