C DEPO      SOURCE    CHAT      05/01/12    22:42:46     5004           
C DEPO     SOURCE    INSL       24/10/96    
      SUBROUTINE DEPO(S1,DEP,PAEC,SEQ,NSTRS,IFOU,D,DP,EX,PXY,AA,BB,
     1 DK1,DK2,RB,ILO)
C
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)
      DIMENSION S1(NSTRS),DEP(NSTRS,NSTRS),DP(NSTRS,NSTRS)
      DIMENSION D(NSTRS,NSTRS),AC(6),AB(6),DGSI(6),DFSI(6)
C
C             *************************************************
C             **  CALCUL DE LA MATRICE ELASTOPLASTIQUE [Dep] **
C             *************************************************
C-------------------------------------------------------------------
      CALL ZERO(DEP,NSTRS,NSTRS)
      CALL ZERO(DP,NSTRS,NSTRS)
      CALL ZERO(AB,6,1)
      CALL ZERO(AC,6,1)
      CALL ZERO(DFSI,6,1)
      CALL ZERO(DGSI,6,1)
C-------------------------------------------------------------------
      CALL MATHOO(D,EX,PXY,NSTRS,IFOU)
      CALL DFSIG(S1,DFSI,DGSI,SEQ,NSTRS,RB,AA,BB,DK1,DK2,ILO)
C
      DO 5 I=1,NSTRS
      DO 5 J=1,NSTRS
        AB(I)=AB(I)+D(I,J)*DGSI(J)
    5 CONTINUE
C
      DO 2 I=1,NSTRS
      DO 2 J=1,NSTRS
       AC(I)=AC(I)+D(J,I)*DFSI(J)
    2 CONTINUE
C
      DO 3 I=1,NSTRS
      DO 3 J=1,NSTRS
       DP(I,J)=DP(I,J)+AB(I)*AC(J)
    3 CONTINUE
C
      H1=0.D0
      DO 4 I=1,NSTRS
        H1=H1+DFSI(I)*AB(I)
    4 CONTINUE
C
      HA=H1+PAEC
      DO 1 I=1,NSTRS
      DO 1 J=1,NSTRS
       IF(DABS(HA).LT.1.D-10) THEN
         DP(I,J)=0.D0
       ELSE
         DP(I,J)=DP(I,J)/HA
       ENDIF
       DEP(I,J)=D(I,J)-DP(I,J)
    1 CONTINUE
C-------------------------------------------------------------------
      IECR=0
      IF(IECR.EQ.10) THEN
      WRITE(*,*) '***  S1 DANS DEPO  ***  PAEC=',PAEC,'SEQ=',SEQ
      WRITE(*,1991) (S1(IA),IA=1,NSTRS)
      WRITE(*,*) '***  DFSI DANS DEPO  ***  IFOU=',IFOU,'NSTRS=',NSTRS
      WRITE(*,1991) (DFSI(IA),IA=1,NSTRS)
      WRITE(*,*) '***  DGSI ***  H1=',H1,' HA=',HA
      WRITE(*,1991) (DGSI(IA),IA=1,NSTRS)
      WRITE(*,*) ' ***  D (cont) **   '
      DO 115 IA = 1,NSTRS
        WRITE(*,1991) (D(IA,IC),IC=1,NSTRS)
  115 CONTINUE
      WRITE(*,*) ' ***  DEP **  '
      DO 114 IA = 1,NSTRS
        WRITE(*,1991) (DEP(IA,IC),IC=1,NSTRS)
  114 CONTINUE
      ENDIF
1991  FORMAT(18(1X,E12.5))
C-------------------------------------------------------------------
      RETURN
      END