C CUBEIT    SOURCE    CHAT      05/01/12    22:32:27     5004           
      SUBROUTINE CUBEIT(ICM,XE,XEC,XX,SHPC,SGA,QSI,IG)
      IMPLICIT INTEGER(I-N)
      IMPLICIT  REAL*8(A-H,O-Z)  
      DIMENSION A(3,8),AJ(3,3),X(3),XE(3,*),XEC(3,2),XX(3,2),
     & BJ(3,3),F(3),SHPC(6,20,*),SGA(3,5,5),QSI(3,2),DT(3),SIB(3)
      DATA EPSI/1.D-7/
C --- IG: NUMERO DU POINT DE GAUSS
      DO 10 I=1,3
      S11=XE(I,1)+XE(I,2)
      S22=XE(I,1)-XE(I,2)
      T11=XE(I,3)+XE(I,4)
      T22=XE(I,3)-XE(I,4)
      U11=XE(I,5)+XE(I,6)
      U22=XE(I,5)-XE(I,6)
      V11=XE(I,7)+XE(I,8)
      V22=XE(I,7)-XE(I,8)
      A(I,1)= S11+T11+U11+V11-8.D0*XX(I,IG)
      A(I,2)=-S22+T22-U22+V22
      A(I,3)=-S11+T11-U11+V11
      A(I,4)=-S11-T11+U11+V11
      A(I,5)= S22+T22+U22+V22
      A(I,6)= S11-T11-U11+V11
      A(I,7)= S22-T22-U22+V22
  10  A(I,8)=-S22-T22+U22+V22
C --- Initialisation  
      DO 15 I=1,3
  15  X(I)=0.0
C
      ITER=0
      ICRI=0
 100  CONTINUE
C --- LES DERIVEES DES FONCTIONS DE TRANSFORMATION
      X12=X(1)*X(2)
      X23=X(2)*X(3)
      X31=X(3)*X(1)
      DO 20 I=1,3
      AJ(I,1)=A(I,2)+A(I,5)*X(2)+A(I,7)*X(3)+A(I,8)*X23
      AJ(I,2)=A(I,3)+A(I,5)*X(1)+A(I,6)*X(3)+A(I,8)*X31
  20  AJ(I,3)=A(I,4)+A(I,6)*X(2)+A(I,7)*X(1)+A(I,8)*X12
C --- Calcul de l'inverse de la matrice AJ et son determinant :BJ=inverse(AJ)
      CALL INVERT(AJ,BJ,DET,ICRI)
      DO 40 I=1,3
  40  F(I)=A(I,1)+A(I,2)*X(1)+A(I,3)*X(2)+A(I,4)*X(3)+A(I,5)*X12
     &    +A(I,6)*X23+A(I,7)*X31+A(I,8)*X(1)*X23
      DD=SQRT(F(1)*F(1)+F(2)*F(2)+F(3)*F(3))
      IF(DD.GT.EPSI) THEN
      ITER=ITER+1
      DO 50 I=1,3
  50  X(I)=X(I)-BJ(I,1)*F(1)-BJ(I,2)*F(2)-BJ(I,3)*F(3)
      GOTO 100
      END IF
      DO 60 I=1,3
  60  QSI(I,IG)=X(I)
      C=0.125D0
      A1=1.D0+X(1)
      A2=1.D0-X(1)
      B1=1.D0+X(2)
      B2=1.D0-X(2)
      C1=1.D0+X(3)
      C2=1.D0-X(3)
C --- Calcul des fonctions d'interpolation leur derivees
C --- Derivee de Ni par rapport a QSI
      SHPC(2,1,IG)=-B2*C2*C
      SHPC(2,2,IG)=-SHPC(2,1,IG)
      SHPC(2,3,IG)= B1*C2*C
      SHPC(2,4,IG)=-SHPC(2,3,IG)
      SHPC(2,5,IG)=-B2*C1*C
      SHPC(2,6,IG)=-SHPC(2,5,IG)
      SHPC(2,7,IG)= B1*C1*C
      SHPC(2,8,IG)=-SHPC(2,7,IG)
      IF(ICM.NE.0) THEN
C --- Derivee de Ni par rapport a ETA
      SHPC(3,1,IG)=-A2*C2*C
      SHPC(3,2,IG)=-A1*C2*C
      SHPC(3,3,IG)=-SHPC(3,2,IG)
      SHPC(3,4,IG)=-SHPC(3,1,IG)
      SHPC(3,5,IG)=-A2*C1*C
      SHPC(3,6,IG)=-A1*C1*C
      SHPC(3,7,IG)=-SHPC(3,6,IG)
      SHPC(3,8,IG)=-SHPC(3,5,IG)
C --- Derivee de Ni par rapport a DZE
      SHPC(4,1,IG)=-A2*B2*C
      SHPC(4,2,IG)=-A1*B2*C
      SHPC(4,3,IG)=-A1*B1*C
      SHPC(4,4,IG)=-A2*B1*C
      SHPC(4,5,IG)=-SHPC(4,1,IG)
      SHPC(4,6,IG)=-SHPC(4,2,IG)
      SHPC(4,7,IG)=-SHPC(4,3,IG)
      SHPC(4,8,IG)=-SHPC(4,4,IG)
      END IF
C --- Fonctions d'interpolation Ni
      SHPC(1,1,IG)=-A2*SHPC(2,1,IG)
      SHPC(1,2,IG)= A1*SHPC(2,2,IG)
      SHPC(1,3,IG)= A1*SHPC(2,3,IG)
      SHPC(1,4,IG)=-A2*SHPC(2,4,IG)
      SHPC(1,5,IG)=-A2*SHPC(2,5,IG)
      SHPC(1,6,IG)= A1*SHPC(2,6,IG)
      SHPC(1,7,IG)= A1*SHPC(2,7,IG)
      SHPC(1,8,IG)=-A2*SHPC(2,8,IG)
      CALL PROSGA(ICM,XE,XEC,XX,X,SHPC,SGA,QSI,IG,8)
      END