C CRIDAM    SOURCE    CHAT      05/01/12    22:30:15     5004           
      SUBROUTINE CRIDAM(SIGG,NSTRS,VARR,XMAT,NCOMAT,XCAR,ICARA,                 
     1INPLAS,NTRAC,TRACC,NC,NPNTER,NNVARI,MFR,XF,KERRE,SIGGD,
     2YY,T,TRAC,NCOURB)                           
C                                                                               
C ===================================================================           
C CE SOUS-PROGRAMME EST APPELE PAR "ENDOM".                                     
C IL CALCULE LA VALEUR DU CRITERE POUR CHAQUE MODELE DE MATERIAU                
C ENDOMMAGEABLE.                                                                
C                                                                               
C ENTREES:                                                                      
C -------                                                                       
C NSTRS        = NBR. DE COMPOSANTES DES CONTR. OU DES DEFORM.                  
C SIGG(NSTRS)  = CONTR.                                                         
C NNVARI       = NBR. DE VARIABLES INTERNES PILOTANT LES EQUATIONS              
C                DU MODELE                                                      
C VARR(2)...   = VARIABLES INTERNES PILOTANT LES EQUATIONS DU MODELE            
C ...VARR(1+NNVARI)                                                             
C NCOMAT       = NBR. DE CARACTERISTIQUES MECANIQUES DU MATERIAU                
C XMAT(NCOMAT) = CARACTERISTIQUES MECANIQUES DU MATERIAU                        
C MFR          = INDICE DE LA FORMULATION MECANIQUE; SEULEMENT                  
C                MASSIF OU COQUE POUR LES MATERIAUX ENDOMMAGEABLES              
C ICARA        = NBR. DE CARACT. GEOMETRIQUES DES ELEMENTS FINIS                
C XCAR(ICARA)  = CARACT. GEOMETRIQUES DES ELEMENTS FINIS                        
C INPLAS       = INDICE DU MODELE DECRIVANT LE MATERIAU ENDOMMAGEABLE           
C NTRAC        = DIMENSION DE TRACC                          
C TRACC(NTRAC)  = COURBES DE TRACTION
C NC           = NBR. DE COURBES DE TRACTION
C NPNTER(NC)= TABLEAU CONTENANT LE NOMBRE DE POINTS POUR CHAQUE
C                COURBE DE TRACTION (A T FIXEE)
C T            = TEMPERATURE A LAQUELLE ON CALCULE LE CRITERE                                             
C                                                                               
C SORTIES:                                                                      
C -------                                                                       
C XF= VALEUR DU CRITERE                                                         
C KERRE= INDICE QUI REGIT LES ERREURS                                           
C      = 77 SI LA DEFORM. PLAST. CUMULEE ENDOMMAGEE (VARIABLE VIR)              
C           EST EN DEHORS DE LA COURBE DE TRACTION, DS. LE CAS DE               
C           L'ECROUISSAGE ET DE L'ENDOMMAGEMENT ISOTROPES                       
C      = 99 SI LA FORMULATION MECANIQUE N'EST PAS DISPONIBLE POUR               
C           LE MODELE CONSIDERE                                                 
C                                                                               
C ==================================================================            
C                                                                               
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8 (A-H,O-Z)                                                 
      DIMENSION SIGG(*),VARR(*),XMAT(*),XCAR(*),TRACC(*),SIGGD(*),
     1          TRAC(*),NPNTER(*)                
C                                                                               
      KERRE=0                                                                   
      IPLAS=INPLAS-25
C                                                                               
C -------------------------------------------------------------                 
C LE CALCUL DU CRITERE DEPEND DU MODELE DONC DE INPLAS OU IPLAS                 
C -------------------------------------------------------------                 
      GOTO (10,1000,1000) IPLAS                                                 
C                                                                               
C                                                                               
C ==================================================                            
C ECROUISSAGE ET ENDOMMAGEMENT ISOTROPES - VON MISES                            
C ==================================================                            
   10 VIR=VARR(2)                                                               
      XD=VARR(3)                                                                
C                                                                               
      IF (MFR.NE.1) GOTO 50                                                     
C                                                                               
C -------                                                                       
C MASSIFS                                                                       
C -------                                                                       
C                                                                               
      CALL TRACTT(TRACC,NPNTER,TRAC,NTRAC,NC,NCOURB,T)
      N2COUR=2*NCOURB
      CALL DERTRA(N2COUR,TRAC,VIR,YY,YPRIM,XINF,XSUP)                                
C                                                                               
      TRACE=SIGG(1)+SIGG(2)+SIGG(3)                                             
C                                                                               
C ..............................                                                
C CALCUL DU DEVIATEUR DES CONTR.                                                
C ..............................                                                
      CALL ZDANUL(SIGGD,NSTRS)                                                  
      DO 30 I=1,NSTRS                                                           
                       A=0.D0                                                   
                       IF (I.LE.3) A=1.D0/3.D0                                  
                       SIGGD(I)=SIGG(I)-A*TRACE                                 
   30 CONTINUE                                                                  
C                                                                               
C ............................................                                  
C CALCUL DE LA CONTR. EQUIVALENTE DE VON MISES                                  
C ............................................                                  
      SIGEQI=PROCON(SIGGD,SIGGD,NSTRS)                                          
      SIGEQI=DSQRT((3.D0/2.D0)*SIGEQI)                                          
C                                                                               
C .................                                                             
C CALCUL DU CRITERE                                                             
C .................                                                             
      XF=SIGEQI/(1.D0-XD)-YY                                                     
      GOTO 1000                                                                 
C                                                                               
   50 IF (MFR.NE.5) GOTO 998                                                    
C                                                                               
C ---------------------------------------                                       
C COQUES EPAISSES - NON ENCORE DISPONIBLE                                       
C ---------------------------------------                                       
C                                                                               
  998 KERRE=99                                                                  
 1000 CONTINUE                                                                  
      RETURN                                                                    
      END