C CALEVO    SOURCE    CHAT      05/01/12    21:45:52     5004           
       SUBROUTINE CALEVO(TEMP0,NMAX,TABMOD,INDICE,GAMMA,TR1)
*
      IMPLICIT INTEGER(I-N)
       IMPLICIT REAL*8(A-H,O-Z)      
-INC CCOPTIO
*
       REAL*8 TEMP0(0:100),POND(0:100),TR1(0:4)
       REAL*8 GAMMA(0:4),TABMOD(0:100,0:10) 
       REAL*8 A(0:4,0:4),B(0:4)
*
*      calcul des coefficients de ponderation
*
       NDIM=5
       TMP=2.*(TEMP0(NMAX)-TEMP0(0))/FLOAT(NMAX)
       DO 10 I=1,NMAX-1
         POND(I)=(TEMP0(I+1)-TEMP0(I-1))/TMP
10     CONTINUE
       POND(0)=2.*(TEMP0(1)-TEMP0(0))/TMP
       POND(NMAX)=2.*(TEMP0(NMAX)-TEMP0(NMAX-1))/TMP
*
*      calcul des temps de relaxation
*
       TR1(0)=0.
       TR1(1)=1.    
       TR1(2)=1./10.
       TR1(3)=1./100.
       TR1(4)=1./1000.
*
*      calcul des modules de Maxwell
*
        DO 20 I=0,4
          DO 21 J=0,4
            A(I,J)=.0
21        CONTINUE
          B(I)=.0
20     CONTINUE
*
*
       DO 30 I=0,4
         DO 31 J=0,4
           DO 32 K=0,NMAX
             A(I,J)=A(I,J)+POND(K)*DEXP(-TEMP0(K)*TR1(I))
     1                *DEXP(-TEMP0(K)*TR1(J))
32         CONTINUE
31       CONTINUE
         DO 33 K=0,NMAX 
           B(I)=B(I)+POND(K)*DEXP(-TEMP0(K)*TR1(I))
     2              *TABMOD(K,INDICE)
33       CONTINUE
30     CONTINUE
*
       CALL SODIRI(A,GAMMA,B,5,NDIM,KERRE)
       IF(KERRE.EQ.49) CALL ERREUR(49)
*
       END